xtext-core/gradle/bootstrap-setup.gradle
Christian Dietrich 81cfb9b6f7 update to xtext-gradle-plugin 2.0.9
Signed-off-by: Christian Dietrich <christian.dietrich@itemis.de>
2021-08-28 21:14:24 +02:00

36 lines
1.1 KiB
Groovy

apply plugin: "org.gradle.java-base"
/*
* Root project configuration that is reused by subprojects to apply the Xtend compiler.
*/
if (!hasProperty('JENKINS_URL')) {
ext.JENKINS_URL = 'https://ci.eclipse.org/xtext'
}
// The repositories to query when constructing the Xtend compiler classpath
repositories {
mavenCentral()
maven {
name 'xtend-bootstrap'
url "$JENKINS_URL/job/xtend-bootstrap/lastStableBuild/artifact/build-result/maven-repository/"
}
}
configurations {
xtendCompiler {
description 'Bootstrap dependencies for the Xtend compiler'
resolutionStrategy {
eachDependency {
if (requested.group == 'org.eclipse.xtext' || requested.group == 'org.eclipse.xtend')
useVersion(versions.xtext_bootstrap)
}
}
exclude group: 'asm'
}
}
dependencies {
xtendCompiler "org.eclipse.xtend:org.eclipse.xtend.core:${versions.xtext_bootstrap}"
xtendCompiler "org.eclipse.xtext:org.eclipse.xtext.java:${versions.xtext_bootstrap}"
xtendCompiler "org.eclipse.xtext:org.eclipse.xtext.smap:${versions.xtext_bootstrap}"
xtendCompiler platform("org.eclipse.xtext:xtext-dev-bom:${versions.xtext_bootstrap}")
}