/*
 * Root project for xtext-core.
 */

import java.time.format.DateTimeFormatter
import java.time.LocalDateTime

buildscript {
	apply from: "${rootDir}/gradle/versions.gradle"
	repositories {
		jcenter()
		maven {
			url 'http://services.typefox.io/open-source/jenkins/job/gradle-plugins/lastStableBuild/artifact/build/maven-repository/'
		}
	}
	dependencies {
		classpath "org.xtext:xtext-gradle-plugin:$versions.xtend_plugin"
		classpath 'io.typefox.gradle:io.typefox.gradle.p2gen:0.1.0'
	}
}

apply from: "${rootDir}/gradle/versions.gradle"
apply from: "${rootDir}/gradle/bootstrap-setup.gradle"
apply from: "${rootDir}/gradle/p2-deployment.gradle"

ext.buildTime = DateTimeFormatter.ofPattern('yyyyMMdd-HHmm').format(LocalDateTime.now())

subprojects {
	group = 'org.eclipse.xtext'
	version = rootProject.version
	
	apply plugin: 'java'
	if (findProperty('skipXtendCompiler') != 'true') {
		apply plugin: 'org.xtext.xtend'
	}
	apply plugin: 'eclipse'
	apply plugin: 'maven'
	
	apply from: "${rootDir}/gradle/upstream-repositories.gradle"
	apply from: "${rootDir}/gradle/java-compiler-settings.gradle"
	apply from: "${rootDir}/gradle/xtend-compiler-settings.gradle"
	apply from: "${rootDir}/gradle/maven-deployment.gradle"
	apply from: "${rootDir}/gradle/eclipse-project-layout.gradle"
	apply from: "${rootDir}/gradle/manifest-gen.gradle"
	apply from: "${rootDir}/gradle/validation.gradle"
}

task clean(type: Delete) {
	group 'Build'
	description 'Deletes the local repositories'
	delete 'build'
}